61 lines
2.6 KiB
Text
61 lines
2.6 KiB
Text
# ===========================================================================
|
|
# https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
|
|
# ===========================================================================
|
|
#
|
|
# SYNOPSIS
|
|
#
|
|
# AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
|
|
#
|
|
# DESCRIPTION
|
|
#
|
|
# Check whether the given FLAG works with the current language's compiler
|
|
# or gives an error. (Warnings, however, are ignored)
|
|
#
|
|
# ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
|
|
# success/failure.
|
|
#
|
|
# If EXTRA-FLAGS is defined, it is added to the current language's default
|
|
# flags (e.g. CFLAGS) when the check is done. The check is thus made with
|
|
# the flags: "CFLAGS EXTRA-FLAGS FLAG". This can for example be used to
|
|
# force the compiler to issue an error when a bad flag is given.
|
|
#
|
|
# INPUT gives an alternative input source to AC_COMPILE_IFELSE.
|
|
#
|
|
# NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
|
|
# macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
|
|
#
|
|
# NOTE: This implementation was extended with check for compiler complaints
|
|
#
|
|
# LICENSE
|
|
#
|
|
# Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
|
|
# Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
|
|
# Copyright (c) 2022 Jim Klimov <jimklimov+nut@gmail.com>
|
|
#
|
|
# Copying and distribution of this file, with or without modification, are
|
|
# permitted in any medium without royalty provided the copyright notice
|
|
# and this notice are preserved. This file is offered as-is, without any
|
|
# warranty.
|
|
|
|
#serial 6
|
|
|
|
AC_DEFUN([AX_CHECK_COMPILE_FLAG],
|
|
[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
|
|
AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
|
|
AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
|
|
ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
|
|
_AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
|
|
AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
|
|
[dnl Toolkit per se did not return an error code; but did it complain?
|
|
dnl Below are a few strings typical for some versions of GCC and CLANG
|
|
dnl This relies on AC_COMPILE_IFELSE implementation retaining conftest.err
|
|
AS_IF([grep -E '(unrecognized.* option|did you mean|unknown argument:)' < conftest.err >/dev/null 2>/dev/null],
|
|
[AS_VAR_SET(CACHEVAR,[no])],dnl Hit a complaint, flag is not supported after all
|
|
[AS_VAR_SET(CACHEVAR,[yes])])],
|
|
[AS_VAR_SET(CACHEVAR,[no])])
|
|
_AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
|
|
AS_VAR_IF(CACHEVAR,yes,
|
|
[m4_default([$2], :)],
|
|
[m4_default([$3], :)])
|
|
AS_VAR_POPDEF([CACHEVAR])dnl
|
|
])dnl AX_CHECK_COMPILE_FLAGS
|